blob: e4224aa783867a1420c03bb4866b71cb59186997 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
/* Make this with: lex delatex.lex; cc lex.yy.c -ll -o delatex */
L [A-Za-z]
%Start Display Math Normal Tag VerbPlus Bracket
%%
<Normal>\' {yyleng--; yymore(); /* ignore apostrophes */}
<Normal>{L}+\\- {yyleng-=2; yymore(); /* ignore hyphens */}
<Normal>[a-zA-Z0-9_]+@[a-zA-Z0-9_.]+ ; /* ignore email addresses */
<Normal>[a-z]/[^A-Za-z] ; /* ignore single letter "words" */
<Normal>[A-Z]+ ; /* ignore words all in uppercase */
<Normal>{L}+('{L}*)*{L} {printf("%s\n",yytext); /* any other letter seq is a word */}
<Normal>"%".* ; /* ignore comments */
<Normal>\\{L}+ ; /* ignore other control sequences */
<Normal>"\\begin{" BEGIN Tag; /* ignore this and up to next "}" */
<Normal>"\\bibitem{" BEGIN Tag;
<Normal>"\\bibliography{" BEGIN Tag;
<Normal>"\\bibstyle{" BEGIN Tag;
<Normal>"\\cite{" BEGIN Tag;
<Normal>"\\end{" BEGIN Tag;
<Normal>"\\include{" BEGIN Tag;
<Normal>"\\includeonly{" BEGIN Tag;
<Normal>"\\input{" BEGIN Tag;
<Normal>"\\label{" BEGIN Tag;
<Normal>"\\pageref{" BEGIN Tag;
<Normal>"\\ref{" BEGIN Tag;
<Normal>"\\verb+" BEGIN VerbPlus;
<Normal>"\\documentclass[" BEGIN Bracket;
<Normal>"\\documentclass{" BEGIN Tag;
<Normal>"\\usepackage[" BEGIN Bracket;
<Normal>"\\usepackage{" BEGIN Tag;
<Bracket>[^\]] ;
<Bracket>"][" ;
<Bracket>"]{" BEGIN Tag;
<Bracket>"]" BEGIN Normal;
<Tag>[^}] ; /* ignore things up to next "}" */
<Tag>"}" BEGIN Normal;
<VerbPlus>[^+] ; /* ignore thing up to next "+" */
<VerbPlus>"+" BEGIN Normal;
<Normal>[0-9]+ ; /* ignore numbers */
<Normal>"\\(" BEGIN Math; /* begin latex math mode */
<Math>"\\)" BEGIN Normal; /* end latex math mode */
<Math>.|\\[^)]|\n ; /* ignore anything else in latex math mode */
<Normal>"\\[" BEGIN Display; /* now in Latex display mode */
<Display>[^$]|\\[^\]] ; /* ignore most things in display math mode */
<Display>"\\]" BEGIN Normal; /* get out of Display math mode */
<Normal>\\. ; /* ignore other single character control sequences */
<Normal>\\\n ; /* more of the same */
<Normal>\n|. ; /* ignore anything else, a character at a time */
%%
#include <stdio.h>
#include <stdlib.h>
int
main(int argc, char **argv)
{
int i;
if (argc==1) {
yyin = stdin;
BEGIN Normal; /* Starts yylex off in the right state */
yylex();
}
else for (i=1; i<argc; i++) {
yyin = fopen(argv[i],"r");
if (yyin==NULL) {
fprintf(stderr,"can't open %s\n",argv[i]);
exit(1);
}
BEGIN Normal; /* Starts yylex off in the right state */
yylex();
}
exit(0);
}
int
yywrap(void)
{
return 1;
}
|